フィードバック線形化を使った推定器の設計 

フィードバック線形化は，線形手法を使う非線形推定器の設計にも使える．船体の長さが で速度が の船に対するヨー角 とヨーレート を，Norrbinのモデルとフィードバック線形化に基づいて推定する． »

In[1]:=

X pars = {Subscript[n, 3] -> 1, Subscript[n, 1] -> 1, Subscript[n, 2] -> 0, Subscript[n, 0] -> 0};

In[2]:=

X asys = AffineStateSpaceModel[(2 l/v) \[Psi]''[t] + Subscript[n, 3] \[Psi]'[t]^3 + Subscript[n, 2] \[Psi]'[t]^2 + Subscript[n, 1] \[Psi]'[t] + Subscript[n, 0] == (v/l) \[Delta][t], \[Psi][t], \[Delta][t], \[Psi][t], t] /. pars /. {l -> 45}

Out[2]=

モデルは完全にフィードバック線形化が可能である．

In[3]:=

X \[ScriptCapitalF] = FeedbackLinearize[asys]

Out[3]=

極配置を使って推定器のゲインを計算する．

In[4]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]

Out[4]=

非線形推定器を組み立てる．

In[5]:=

X EstimatorGains[\[ScriptCapitalF]["LinearSystem"], {-2 + I, -2 - I}]; \[ScriptL] = \[ScriptCapitalF][{"OriginalSystemEstimator", %}]

Out[5]=

特定の船の速度に対する推定の状態軌道をプロットする．

In[6]:=

X inp = -UnitStep[t] + UnitStep[t - 1]; ics = {-2, 1};

In[7]:=

X esr = OutputResponse[ SystemsModelDelete[\[ScriptL] /. v -> 5, None, -1], Join[{inp}, OutputResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]], {t, 0, 10}];

In[8]:=

X Plot[esr, {t, 0, 10}, PlotStyle -> Dashed, PlotRange -> All, PlotLegends -> {"Yaw (\[Psi])", "Yaw rate (\[Psi]')"}]

Out[8]=

実際の状態軌道を計算する．

In[9]:=

X sr = StateResponse[{asys /. v -> 5, ics}, inp, {t, 0, 10}]

Out[9]=

実際と推定のヨー角とヨーレートを計算する．

In[10]:=

X Table[Plot[{sr[[i]], esr[[i]]}, {t, 0, 5}, PlotStyle -> {Automatic, Dashed}, PlotLegends -> {"Actual", "Estimated"}, PlotRange -> All, PlotLabel -> Switch[i, 1, "Yaw Angle", _, "Yaw rate"]], {i, {1, 2}}]

Out[10]=