Zustandsraumtransformation 

Beschreiben Sie die maßgebenden Gleichungen eines sphärischen Pendels in kartesischen Koordinaten, bringen Sie sie in die Form eines affinen Zustandsraums und konvertieren Sie diese in sphärische Koordinaten.

Die maßgebenden Gleichungen hergeleitet von der Lagrange-Funktion.

In[1]:=

X \[ScriptCapitalL] = 1/2 m (x'[t]^2 + y'[t]^2 + (x[t] x'[t] + y[t] y'[t])^2/( r^2 - x[t]^2 - y[t]^2)) + m g Sqrt[r^2 - x[t]^2 - y[t]^2];

In[2]:=

X Short[eqns = Table[D[D[\[ScriptCapitalL], q'[t]], t] - D[\[ScriptCapitalL], q[t]] == Subscript[F, q][t], {q, {x, y}}]]

Out[2]//Short=

Die affine Darstellung mit Zuständen und Eingangsgrößen .

In[3]:=

X Short[eqns = Table[D[D[\[ScriptCapitalL], q'[t]], t] - D[\[ScriptCapitalL], q[t]] == Subscript[F, q][t], {q, {x, y}}]]; AffineStateSpaceModel[ eqns, {x[t], y[t], x'[t], y'[t]}, {Subscript[F, x][t], Subscript[F, y][t]}, {Sqrt[r^2 - x[t]^2 - y[t]^2]}, t]; assm = AffineStateSpaceModel[%, {x, y, Subscript[x, d], Subscript[y, d]}] // Simplify

Out[3]=

Die Transformation zwischen sphärischen und kartesischen Koordinaten:

In[4]:=

X ctrans = Most@ CoordinateTransform[ "Spherical" -> "Cartesian", {r, \[Theta][t], \[Phi][t]}]

Out[4]=

Die Transformation der Koordinatenableitungen:

In[5]:=

X ctransd = D[ctrans, t] /. {\[Theta]' -> Subscript[\[Theta], d], \[Phi]' -> Subscript[\[Phi], d]}

Out[5]=

Die vollständige Zustandstransformation:

In[6]:=

X trans = Thread[{x[t], y[t], Subscript[x, d][t], Subscript[y, d][t]} -> Join[ctrans, ctransd]]

Out[6]=

Die Beschreibung in sphärischen Koordinaten ist viel einfacher.

In[7]:=

X StateSpaceTransform[ assm, {trans, {\[Theta][t], Subscript[\[Theta], d][t], \[Phi][t], Subscript[\[Phi], d][t]}}] // PowerExpand

Out[7]=