Den Lösungsprozess steuern 

Extrahieren Sie interne Details oder unterbrechen und steuern Sie viele Aspekte des Lösungsprozesses.

Verwenden Sie das Finite-Elemente-Paket.

In[1]:=

X Needs["NDSolve`FEM`"]

Definieren Sie eine Region und erzeugen Sie ein Gitternetz mit minimaler Bandbreite.

In[2]:=

X \[CapitalOmega] = ImplicitRegion[ 0 <= x <= 2 && 0 <= y <= 0.5 && ! (x >= 1 && y <= 0.1) && ! (x >= 1 && y >= 0.4), {x, y}]; \[CapitalMu] = ToElementMesh[\[CapitalOmega], "NodeReordering" -> True]

Out[2]=

Definieren Sie einen Dehnungsoperator.

In[3]:=

X planeStrainOperator[ Y_, \[Nu]_] := {Inactive[ Div][({{0, -((Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu])))}, {-(Y/( 2 (1 + \[Nu]))), 0}}.Inactive[Grad][v[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-((Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}, {0, -(Y/(2 (1 + \[Nu])))}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}], Inactive[ Div][({{0, -(Y/(2 (1 + \[Nu])))}, {-(( Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-(Y/(2 (1 + \[Nu]))), 0}, {0, -(( Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu])))}}.Inactive[ Grad][v[x, y], {x, y}]), {x, y}]};

Stellen Sie die Gleichungen auf.

In[4]:=

X {nds} = NDSolve`ProcessEquations[{planeStrainOperator[10^3, 33/100] == {0, NeumannValue[-1, x == 2]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y} \[Element] \[CapitalMu]]

Out[4]=

Untersuchen Sie die Daten der finiten Elemente.

In[5]:=

X nds["FiniteElementData"]["Properties"]

Out[5]=

Extrahieren Sie die Verfahrensdaten.

In[6]:=

X methodData = nds["FiniteElementData"]["FEMMethodData"]

Out[6]=

Extrahieren Sie die Daten der PDG-Koeffizienten.

In[7]:=

X pdeData = nds["FiniteElementData"]["PDECoefficientData"]

Out[7]=

Extrahieren Sie die Lösungsdaten.

In[8]:=

X solutionData = nds["SolutionData"][[1]];

Diskretisieren Sie die PDG.

In[9]:=

X dPDE = DiscretizePDE[pdeData, methodData, solutionData]

Out[9]=

Extrahieren und visualisieren Sie die Steifigkeitsmatrix.

In[10]:=

X s = dPDE["StiffnessMatrix"]; MatrixPlot[s]

Out[10]=