Controle el proceso de solución 

Extraiga detalles internos o intercepte y controle muchos aspectos del proceso de solución.

Cargue el paquete de elemento finito.

In[1]:=

X Needs["NDSolve`FEM`"]

Especifique una región y cree una malla con banda ancha mínima.

In[2]:=

X \[CapitalOmega] = ImplicitRegion[ 0 <= x <= 2 && 0 <= y <= 0.5 && ! (x >= 1 && y <= 0.1) && ! (x >= 1 && y >= 0.4), {x, y}]; \[CapitalMu] = ToElementMesh[\[CapitalOmega], "NodeReordering" -> True]

Out[2]=

Especifique un operador de tensión de plano.

In[3]:=

X planeStrainOperator[ Y_, \[Nu]_] := {Inactive[ Div][({{0, -((Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu])))}, {-(Y/( 2 (1 + \[Nu]))), 0}}.Inactive[Grad][v[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-((Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}, {0, -(Y/(2 (1 + \[Nu])))}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}], Inactive[ Div][({{0, -(Y/(2 (1 + \[Nu])))}, {-(( Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-(Y/(2 (1 + \[Nu]))), 0}, {0, -(( Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu])))}}.Inactive[ Grad][v[x, y], {x, y}]), {x, y}]};

Establezca las ecuaciones.

In[4]:=

X {nds} = NDSolve`ProcessEquations[{planeStrainOperator[10^3, 33/100] == {0, NeumannValue[-1, x == 2]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y} \[Element] \[CapitalMu]]

Out[4]=

Inspeccione los datos de elementos finitos.

In[5]:=

X nds["FiniteElementData"]["Properties"]

Out[5]=

Extraiga los datos de método.

In[6]:=

X methodData = nds["FiniteElementData"]["FEMMethodData"]

Out[6]=

Extraiga los datos de coeficiente de PDE.

In[7]:=

X pdeData = nds["FiniteElementData"]["PDECoefficientData"]

Out[7]=

Extraiga los datos de solución.

In[8]:=

X solutionData = nds["SolutionData"][[1]];

Discretice el PDE.

In[9]:=

X dPDE = DiscretizePDE[pdeData, methodData, solutionData]

Out[9]=

Extraiga y visualice la matriz de rigidez.

In[10]:=

X s = dPDE["StiffnessMatrix"]; MatrixPlot[s]

Out[10]=