Controle o processo de resolução 

Extraia detalhes internos ou intercepte e controle muitos aspectos do processo de resolução.

Carregue o pacote de elementos finitos.

In[1]:=

X Needs["NDSolve`FEM`"]

Especifique uma região e crie uma malha com largura de banda mínima.

In[2]:=

X \[CapitalOmega] = ImplicitRegion[ 0 <= x <= 2 && 0 <= y <= 0.5 && ! (x >= 1 && y <= 0.1) && ! (x >= 1 && y >= 0.4), {x, y}]; \[CapitalMu] = ToElementMesh[\[CapitalOmega], "NodeReordering" -> True]

Out[2]=

Especifique um operador de deformação plana.

In[3]:=

X planeStrainOperator[ Y_, \[Nu]_] := {Inactive[ Div][({{0, -((Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu])))}, {-(Y/( 2 (1 + \[Nu]))), 0}}.Inactive[Grad][v[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-((Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}, {0, -(Y/(2 (1 + \[Nu])))}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}], Inactive[ Div][({{0, -(Y/(2 (1 + \[Nu])))}, {-(( Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-(Y/(2 (1 + \[Nu]))), 0}, {0, -(( Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu])))}}.Inactive[ Grad][v[x, y], {x, y}]), {x, y}]};

Configure as equações.

In[4]:=

X {nds} = NDSolve`ProcessEquations[{planeStrainOperator[10^3, 33/100] == {0, NeumannValue[-1, x == 2]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y} \[Element] \[CapitalMu]]

Out[4]=

Inspecione os dados de elementos finitos.

In[5]:=

X nds["FiniteElementData"]["Properties"]

Out[5]=

Extraia os dados do método.

In[6]:=

X methodData = nds["FiniteElementData"]["FEMMethodData"]

Out[6]=

Extraia os dados de coeficiente da EDP.

In[7]:=

X pdeData = nds["FiniteElementData"]["PDECoefficientData"]

Out[7]=

Extraia os dados da resolução.

In[8]:=

X solutionData = nds["SolutionData"][[1]];

Discretize a EDP.

In[9]:=

X dPDE = DiscretizePDE[pdeData, methodData, solutionData]

Out[9]=

Extraia e visualize a matriz de rigidez.

In[10]:=

X s = dPDE["StiffnessMatrix"]; MatrixPlot[s]

Out[10]=