解の過程を制御する 

解の過程の内部の詳細を抽出するか，多くの側面を防御し制御する．

有限要素法パッケージをロードする．

In[1]:=

X Needs["NDSolve`FEM`"]

領域を指定し，最小のバンド幅でメッシュを生成する．

In[2]:=

X \[CapitalOmega] = ImplicitRegion[ 0 <= x <= 2 && 0 <= y <= 0.5 && ! (x >= 1 && y <= 0.1) && ! (x >= 1 && y >= 0.4), {x, y}]; \[CapitalMu] = ToElementMesh[\[CapitalOmega], "NodeReordering" -> True]

Out[2]=

平面ひずみ演算子を指定する．

In[3]:=

X planeStrainOperator[ Y_, \[Nu]_] := {Inactive[ Div][({{0, -((Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu])))}, {-(Y/( 2 (1 + \[Nu]))), 0}}.Inactive[Grad][v[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-((Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}, {0, -(Y/(2 (1 + \[Nu])))}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}], Inactive[ Div][({{0, -(Y/(2 (1 + \[Nu])))}, {-(( Y \[Nu])/((1 - 2 \[Nu]) (1 + \[Nu]))), 0}}.Inactive[Grad][ u[x, y], {x, y}]), {x, y}] + Inactive[ Div][({{-(Y/(2 (1 + \[Nu]))), 0}, {0, -(( Y (1 - \[Nu]))/((1 - 2 \[Nu]) (1 + \[Nu])))}}.Inactive[ Grad][v[x, y], {x, y}]), {x, y}]};

方程式を設定する．

In[4]:=

X {nds} = NDSolve`ProcessEquations[{planeStrainOperator[10^3, 33/100] == {0, NeumannValue[-1, x == 2]}, DirichletCondition[{u[x, y] == 0., v[x, y] == 0.}, x == 0]}, {u, v}, {x, y} \[Element] \[CapitalMu]]

Out[4]=

有限要素データを調べる．

In[5]:=

X nds["FiniteElementData"]["Properties"]

Out[5]=

メソッドデータを抽出する．

In[6]:=

X methodData = nds["FiniteElementData"]["FEMMethodData"]

Out[6]=

偏微分方程式の係数データを抽出する．

In[7]:=

X pdeData = nds["FiniteElementData"]["PDECoefficientData"]

Out[7]=

解のデータを抽出する．

In[8]:=

X solutionData = nds["SolutionData"][[1]];

偏微分方程式を離散化する．

In[9]:=

X dPDE = DiscretizePDE[pdeData, methodData, solutionData]

Out[9]=

剛性行列を可視化する．

In[10]:=

X s = dPDE["StiffnessMatrix"]; MatrixPlot[s]

Out[10]=