Valores de Neumann transitorios 

Calcule el efecto de enfriamiento de un ducto con un líquido enfriador en una sección transversal axisimétrica de un tubo.

Especifique un dominio de solución.

In[1]:=

X \[CapitalOmega] = ImplicitRegion[ y >= 0 && (x - 3/2)^2 + y^2 >= 1/25 && x^2 + y^2 >= 1 && x^2 + y^2 <= 4 && y <= x Tan[\[Pi]/8], {x, y}];

Especifique un valor de Neumann que dependa en condiciones transitorias de Dirichlet de tiempo.

In[2]:=

X Subscript[\[CapitalGamma], N][t_] = NeumannValue[ If[t <= 10., -100. t, -1000.], (x - 3/2)^2 + y^2 == 1/25];

In[3]:=

X Subscript[\[CapitalGamma], D][ t_] = {DirichletCondition[u[t, x, y] == 200., x^2 + y^2 == 1], DirichletCondition[u[t, x, y] == 15., x^2 + y^2 == 4]};

Resuelva un problema de estado estable correspondiente a las condiciones límite en para encontrar la condición inicial. El generador de malla "Continuation" es utilizado para resolver mejor las esquinas y bordes del dominio .

In[4]:=

X uinit = NDSolveValue[{10 \!\( \*SubsuperscriptBox[\(\[Del]\), \({x, y}\), \(2\)]\(u[0, x, y]\)\) == 0, Subscript[\[CapitalGamma], D][0]}, u[0, x, y], {x, y} \[Element] \[CapitalOmega], Method -> {"PDEDiscretization" -> {"FiniteElement", "MeshOptions" -> {"BoundaryMeshGenerator" -> "Continuation"}}}];

Resuelva una ecuación de calor con una temperatura establecida en los límites exteriores y un flujo dependiente del tiempo en el límite interior, utilizando la solución de estado estable como una condición inicial. Para garantizar la mejor inicialización, la misma malla espacial se utiliza para la solución de estado estacionario.

In[5]:=

X uif = NDSolveValue[{D[u[t, x, y], t] - 10 \!\( \*SubsuperscriptBox[\(\[Del]\), \({x, y}\), \(2\)]\(u[t, x, y]\)\) == Subscript[\[CapitalGamma], N][t], Subscript[\[CapitalGamma], D][0], u[0, x, y] == uinit}, u, {t, 0, 25}, {x, y} \[Element] Head[uinit]["ElementMesh"]];

Grafique la solución.

muestre la entrada completa de Wolfram Languageoculte la entrada

In[6]:=

X framesNTV = Table[ContourPlot[ uif[t, x, y], {x, y} \[Element] uif["ElementMesh"], Mesh -> None, ColorFunction -> "TemperatureMap", Contours -> 21, PlotRange -> All, AspectRatio -> Automatic, Frame -> False], {t, 1/2, 15, 1/2}];

In[7]:=

X Manipulate[framesNTV[[i]], {{i, 9, "time"}, 1, Length[framesNTV], 1}, SaveDefinitions -> True]

Out[7]=

Reproducir Detener