Wolfram Language

Zufallsmatritzen

Wishart- und inverse Wishart-Verteilungen

Die Wishart-Verteilung ist die Verteilung der Kovarianzmatrix von Stichproben aus unabhängigen multinormalen Zufallsvektoren. Sie ist eine Verallgemeinerung der -Verteilung in mehreren Dimensionen. Die Verteilung kommt in multivariaten Statistiken wie der Regression, Kovarianz etc. vor.

Erzeugen Sie eine positiv definite Zufallsmatrix als Parameter für die Wishart-Verteilung.

In[1]:=
Click for copyable input
\[CapitalSigma] = DiagonalMatrix[RandomReal[10, 5]];

Matritzen der Wishart-Verteilung sind symmetrisch und positiv definit.»

In[2]:=
Click for copyable input
dist = WishartMatrixDistribution[30, \[CapitalSigma]]; mat = RandomVariate[dist];
In[3]:=
Click for copyable input
SymmetricMatrixQ[mat] && PositiveDefiniteMatrixQ[mat]
Out[3]=

Die inverse Wishart-Verteilung ist die Verteilung der Kehrmatritzen der Wishart-Verteilung.»

In[4]:=
Click for copyable input
invdist = InverseWishartMatrixDistribution[30, Inverse[\[CapitalSigma]]]; invmat = RandomVariate[invdist];

Matritzen der inversen Wishart-Verteilung sind symmetrisch und positiv definit.

In[5]:=
Click for copyable input
SymmetricMatrixQ[invmat] && PositiveDefiniteMatrixQ[invmat]
Out[5]=

Vergleichen Sie die Eigenwertverteilung für Matritzen der Wishart- und inversen Wishart-Verteilung.

In[6]:=
Click for copyable input
eigs = Flatten[ RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x], x \[Distributed] dist], 10^4]]; inveigs = Flatten[RandomVariate[ MatrixPropertyDistribution[Eigenvalues[x]^-1, x \[Distributed] invdist], 10^4]];
Den kompletten Wolfram Language-Input zeigen
In[7]:=
Click for copyable input
SmoothHistogram[{eigs, inveigs}, PlotLegends -> {"Wishart", "Inverse Wishart"}, Filling -> Axis, ImageSize -> Medium, PlotTheme -> "Scientific"]
Out[7]=

Bei einem Vektor ungleich Null und einer Wishart-Matrix mit Skalenmatrix ist die Statistik -verteilt.

In[8]:=
Click for copyable input
y = #/Sqrt[#.\[CapitalSigma].#] &[RandomReal[1, 5]]; data = RandomVariate[ MatrixPropertyDistribution[y.w.y, w \[Distributed] WishartMatrixDistribution[30, \[CapitalSigma]]], 10^4];
In[9]:=
Click for copyable input
Show[Histogram[data, Automatic, PDF, PlotTheme -> "Detailed"], Plot[PDF[ChiSquareDistribution[30], x], {x, 0, 80}], ImageSize -> Medium]
Out[9]=

Verwandte Beispiele

en es fr ja ko pt-br ru zh