Solución de la ecuación de onda usando su solución fundamental
Defina un operador de onda en una dimensión espacial.
In[1]:=

waveOperator = \!\(
\*SubscriptBox[\(\[PartialD]\), \({t, 2}\)]\(u[x, t]\)\) - \!\(
\*SubscriptBox[\(\[PartialD]\), \({x, 2}\)]\(u[x, t]\)\);
Obtenga su solución fundamental usando GreenFunction.
In[2]:=

gf[x_, t_, y_, s_] =
GreenFunction[waveOperator, u[x, t], {x, -\[Infinity], \[Infinity]},
t, {y, s}]
Out[2]=

Represente gráficamente la solución fundamental.
In[3]:=

Plot3D[gf[x, t, 0, 0] // Evaluate, {x, -4, 4}, {t, 0, 4},
ExclusionsStyle -> Orange, Mesh -> None, AxesLabel -> Automatic]
Out[3]=

Defina una función de fuerza.
In[4]:=

f[y_, s_] := Cos[y] E^(-s)
Resuelva la ecuación de onda con su término de fuerza mediante la evaluación de la integral de convolución .
In[5]:=

sol = Integrate[
gf[x, t, y, s] f[y, s], {y, -\[Infinity], \[Infinity]}, {s,
0, \[Infinity]}, Assumptions -> t > 0 && Im[x] == 0] //
FullSimplify
Out[5]=

Obtenga el resultado usando DSolveValue con condiciones iniciales homogéneas.
In[6]:=

initialc = {u[x, 0] == 0, Derivative[0, 1][u][x, 0] == 0};
In[7]:=

DSolveValue[{waveOperator == f[x, t], initialc}, u[x, t], {x, t}]
Out[7]=

Visualice la onda estacionaria generada por la solución.
In[8]:=

Plot[Table[sol, {t, 0, 1, 0.2}] // Evaluate, {x, -10, 10},
Filling -> Axis]
Out[8]=
