Modelado de una cadena colgante: Nuevo en Wolfram Language 11

Modelado de una cadena colgante

Encuentre la posición con energía potencial mínima de una cadena o cable de longitud suspendida entre dos puntos.

Configure los valores de parámetro para la longitud de la cadena , la altura del extremo izquierdo , y la altura del extremo derecho .

In[1]:=

L = 4; a = 1; b = 3;

Permita que sea la altura de la cadena como una función de posición horizontal, con .

In[2]:=

xf = 1; nh = 201; h := xf/nh;

Configure las variables para la altura de la cadena .

In[3]:=

varsy = Array[y, nh + 1, {0, nh}];

Denote la pendiente en posición por y configure las variables para ésta.

In[4]:=

varsm = Array[m, nh + 1, {0, nh}];

Denote la energía potencial parcial de a por .

In[5]:=

varsv = Array[v, nh + 1, {0, nh}];

Denote la longitud de la cadena en posición por y configure las variables para ésta.

In[6]:=

varss = Array[s, nh + 1, {0, nh}];

Junte todas las variables.

In[7]:=

vars = Join[varsm, varsy, varsv, varss];

El objetivo es minimizar la energía potencial total .

In[8]:=

objfn = v[nh];

Aquí hay restricciones de valores de límite desde la geometría.

In[9]:=

bndcons = {y[0] == a, y[nh] == b, v[0] == 0, s[0] == 0, s[nh] == L};

Discretice las ecuaciones diferenciales ordinarias: , , .

In[10]:=

odecons = {Table[
    y[j + 1] == y[j] + 0.5*h*(m[j] + m[j + 1]), {j, 0, nh - 1}],
   Table[v[j + 1] == 
     v[j] + 0.5*
       h*(y[j]*Sqrt[1 + m[j]^2] + y[j + 1]*Sqrt[1 + m[j + 1]^2]), {j, 
     0, nh - 1}], 
   Table[s[j + 1] == 
     s[j] + 0.5*h*(Sqrt[1 + m[j]^2] + Sqrt[1 + m[j + 1]^2]), {j, 0, 
     nh - 1}]};

Seleccione puntos iniciales para las variables.

In[11]:=

tmin = If[b > a, 0.25 , 0.75]; init = 
 Join[Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}],
  Table[4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a, {k, 0, nh}],
  Table[(4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a)*4*
    Abs[b - a]*((k/nh) - tmin), {k, 0, nh}], 
  Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}]];

Minimice la energía potencial total, sujeta a las restricciones.

In[12]:=

sol = FindMinimum[{objfn, Join[bndcons, odecons]}, 
   Thread[{vars, init}]];

Extraiga los puntos de solución.

In[13]:=

solpts = Table[{i h, y[i] /. sol[[2]]}, {i, 0, nh}];

Represente gráficamente la posición de la cadena con energía potencial mínima.

In[14]:=

ListPlot[solpts, ImageSize -> Medium, PlotTheme -> "Marketing"]

Out[14]=

Utilice FindFit para ajustar el resultado a la curva catenaria.

In[15]:=

catenary[t_] = c1 + (1/c2) Cosh[c2 (t - c3)];

In[16]:=

fitsol = FindFit[solpts, catenary[t], {c1, c2, c3}, {t}]

Out[16]=

Represente gráficamente los puntos de solución junto con la curva catenaria.

In[17]:=

Show[Plot[catenary[t] /. fitsol, {t, 0, 1}, 
  PlotStyle -> Directive[Green, Thickness[0.01]], 
  ImageSize -> Medium], 
 ListPlot[Take[solpts, 1 ;; nh ;; 5], PlotStyle -> PointSize[.02]]]

Out[17]=