反馈线性化  

反馈线性化是一个精确的线性化处理，计算状态和反馈变换以便线性化非线性系统，并允许使用线性技术设计非线性控制器. 根据对磁悬浮系统进行精确和近似的线性化，比较控制器的设计.

可以从控制方程直接获取仿射模型.

In[1]:=

X pars = {R -> 10, L -> 0.05, m -> 0.05, g -> 9.8, c -> 0.05, Subscript[x, 0] -> 0.1};

In[2]:=

X assm = AffineStateSpaceModel[{m x''[t] == m g - c (i[t]/x[t])^2, R i[t] + L i'[t] == V[t]}, {{x[t], Subscript[x, 0]}, {x'[t], 0}, {i[t], Subscript[x, 0] Sqrt[(m g)/c]}}, {{V[t], R Subscript[x, 0] Sqrt[(m g)/c]}}, x[t], t] /. pars

Out[2]=

由于没有残留运动，可完全进行反馈线性化.

In[3]:=

X \[ScriptCapitalF] = FeedbackLinearize[ assm, {{Subscript[z, 1], Subscript[z, 2], Subscript[z, 3]}, v}];

In[4]:=

X \[ScriptCapitalF]["ResidualSystem"]

Out[4]=

使用精确线性化系统计算稳定的反馈增益.

In[5]:=

X \[Kappa]1 = StateFeedbackGains[\[ScriptCapitalF][ "LinearSystem"], {-1.5, -2 + I, -2 - I}]

Out[5]=

对给定初始条件模拟闭环系统.

In[6]:=

X csys1 = \[ScriptCapitalF][{"ClosedLoopSystem", \[Kappa]1}]; ics = {0.3, 0, 0.31305};

In[7]:=

X csys1 = \[ScriptCapitalF][{"ClosedLoopSystem", \[Kappa]1}]; ics = {0.3, 0, 0.31305};; or1 = OutputResponse[{csys1, ics}, 0, {t, 0, 35}]; Plot[%, {t, 0, 6}]

Out[7]=

使用近似线性化系统计算稳定的反馈增益.

In[8]:=

X \[Kappa]2 = StateFeedbackGains[assm, {-1.5, -2 + I, -2 - I}]

Out[8]=

基于精确线性化的设计有更好的响应.

In[9]:=

X csys2 = SystemsModelStateFeedbackConnect[assm, \[Kappa]2]; or2 = OutputResponse[{csys2, ics}, 0, {t, 0, 35}];

In[10]:=

X Plot[{or1, or2}, {t, 0, 35}, PlotLegends -> {"Exact", "Approximate"}]

Out[10]=

使用精确线性化设计的非线性控制器.

In[11]:=

X c1 = \[ScriptCapitalF][{"OriginalSystemFullController", \[Kappa]1}]

Out[11]=

消耗的控制力.

In[12]:=

X inps1 = Join[{0}, sr1 = StateResponse[{csys1, ics}, 0, {t, 0, 35}]]; ce1 = OutputResponse[c1, inps1, {t, 0, 35}];

In[13]:=

X Plot[ce1, {t, 0, 35}, PlotRange -> All]

Out[13]=

对精确范例消耗的力比近似范例更加少.

In[14]:=

X ce2 = -\[Kappa]2 /. Thread[{Subscript[\[FormalX], 1][t], Subscript[\[FormalX], 2][t], Subscript[\[FormalX], 3][t]} -> StateResponse[{csys2, ics}, 0, {t, 0, 35}]];

In[15]:=

X Plot[{ce1, ce2}, {t, 0, 35}, PlotLegends -> {"Exact", "Approximate"}]

Out[15]=

使用非线性控制器浮起的球的动画.

显示完整的 Wolfram 语言输入隐藏输入

In[16]:=

X With[{v = ce1, x = sr1[[1]], i = sr1[[3]]}, Animate[GraphicsGrid[{{AngularGauge[v, {0, 30}, ScaleOrigin -> {\[Pi], 0}, GaugeLabels -> "V"], Graphics[{Rectangle[{-0.65, 0}, {0.65, 3}], Disk[{0, -5 x}, 0.08], Dashed, Line[{{-1, -0.5}, {1, -0.5}}]}, PlotRange -> {{-1, 1}, {-5, 5}}]}, {AngularGauge[i, {0, 5}, ScaleOrigin -> {\[Pi], 0}, GaugeLabels -> "I"], SpanFromAbove}}], {t, 0, 5}, SaveDefinitions -> True, AnimationRunning -> False]]

播放动画 停止播放动画