Regulación de salidas 

Regule la altura del líquido en un taque inferior cuya tasa de red de flujo está sujeta a una perturbación exógena. La entrada de control es el flujo en el tanque superior.

Utilice la ley de Bernoulli y balance de masa para derivar las ecuaciones diferenciales resultantes.

In[1]:=

X eqs = {Subscript[\[ScriptCapitalA], 1] Subscript[\[ScriptH], 1]'[t] == \[ScriptCapitalQ][ t] - \[ScriptC] Subscript[\[ScriptA], 1] Sqrt[ 2 \[ScriptG] Subscript[\[ScriptH], 1][t]], Subscript[\[ScriptCapitalA], 2] Subscript[\[ScriptH], 2]'[t] == \[ScriptC] Subscript[\[ScriptA], 1] Sqrt[ 2 \[ScriptG] Subscript[\[ScriptH], 1][ t]] - \[ScriptC] Subscript[\[ScriptA], 2] Sqrt[ 2 \[ScriptG] Subscript[\[ScriptH], 2][ t]] - \[ScriptCapitalQ]\[ScriptD][ t], \[ScriptCapitalQ]\[ScriptD]'[t] == 0};

Utilice los valores de funcionamiento de estado estacionario .

In[2]:=

X op = {Subscript[\[ScriptH], 1][t] -> \[ScriptQ]^2/( 2 \[ScriptC]^2 \[ScriptG] \!\(\*SubsuperscriptBox[\(\[ScriptA]\), \(1\), \(2\)]\)), Subscript[\[ScriptH], 2][ t] -> (\[ScriptQ] - \[ScriptQ]\[ScriptD])^2/( 2 \[ScriptC]^2 \[ScriptG] \!\(\*SubsuperscriptBox[\(\[ScriptA]\), \(2\), \(2\)]\)), \ \[ScriptCapitalQ]\[ScriptD][ t] -> \[ScriptQ]\[ScriptD], \[ScriptCapitalQ][t] -> \[ScriptQ]}; PowerExpand[eqs /. op]

Out[2]=

Defina el sistema no lineal correspondiente con entrada y salida .

In[3]:=

X pars = {\[ScriptC] -> 0.7, \[ScriptG] -> 9.8, Subscript[\[ScriptCapitalA], 1] -> \[Pi] 4^2, Subscript[\[ScriptA], 1] -> \[Pi] 0.25^2, Subscript[\[ScriptCapitalA], 2] -> \[Pi] 3^2, Subscript[\[ScriptA], 2] -> \[Pi] 0.25^2, \[ScriptQ] -> 1, Subscript[\[ScriptCapitalH], ref] -> 3};

In[4]:=

X dtank = NonlinearStateSpaceModel[eqs, op[[1 ;; 3]], op[[-1]], {Subscript[\[ScriptH], 2][t] - Subscript[\[ScriptCapitalH], ref]}, t] /. pars

Out[4]=

La ley de retroacción.

In[5]:=

X \[ScriptK] = FullInformationOutputRegulator[dtank, {-0.5, -1}] // Simplify

Out[5]=

El sistema de circuito cerrado.

In[6]:=

X csys = SystemsModelStateFeedbackConnect[dtank, \[ScriptK]] // Simplify

Out[6]=

Una perturbación polinómica es aproximada como una función constante por tramos.

In[7]:=

X \[ScriptD] = -0.003 + 0.0013 x + 0.00016 x^2 - 1.613 10^-6 x^3 + 4.069 10^-9 x^4; Subscript[\[ScriptD], \[ScriptA]] = Piecewise[Table[{\[ScriptD], x <= t < x + 1}, {x, 0, 200, 1}], 0.2634];

In[8]:=

X Plot[Subscript[\[ScriptD], \[ScriptA]], {t, 0, 250}, Exclusions -> None]

Out[8]=

Monte el modelo de simulación y simule las respuestas del estado.

In[9]:=

X csys1 = NonlinearStateSpaceModel[csys, Join[op[[1 ;; 2]], {{\[ScriptCapitalQ]\[ScriptD][t], 0}}] /. pars /. \[ScriptQ]\[ScriptD] -> 0] /. \[ScriptQ]\[ScriptD] -> Subscript[\[ScriptD], \[ScriptA]];

In[10]:=

X sr = StateResponse[csys1, 0, {t, 0, 50}];

El gráfico muestra que la regulación deseada ha sido alcanzada.

In[11]:=

X Plot[Evaluate@sr[[{1, 2}]], {t, 0, 30}, PlotLegends -> {"\!\(\*SubscriptBox[\(\[ScriptH]\), \(1\)]\)", "\!\(\*SubscriptBox[\(\[ScriptH]\), \(2\)]\)"}]

Out[11]=