Wolfram Language

Sistemas propios diferenciales

Encuentre los valores propios de AharonovBohm

El efecto de AharonovBohm es un fenómeno mecánico cuántico donde una partícula cargada detecta un potencial de calibre electromagnético, a pesar de que el campo magnético dentro de la región donde la partícula se mueve es cero. En este ejemplo, se considera la ecuación de Schrödinger para un campo magnético fijo concentrado en una línea perpendicular al dominio de la partícula.

Especifique la región como un sector en el plano centrado cerca del eje .

In[1]:=
Click for copyable input
\[CapitalOmega] = Disk[{0, 0}, 1, {-\[Pi]/8, \[Pi]/8}];

Especifique el operador de AharonovBohm. El campo magnético está restringido al eje .

In[2]:=
Click for copyable input
A = 1/2 {-(y - b), x - a}/((x - a)^2 + (y - b)^2) /. {a -> 0.2, b -> 0.4}; \[ScriptCapitalL] = -Laplacian[u[x, y], {x, y}] + I Div[A, {x, y}] u[x, y] + 2 I A.D[u[x, y], {{x, y}}] + A.A u[x, y];

Especifique las condiciones de límite en el límite completo.

In[3]:=
Click for copyable input
\[ScriptCapitalB] = DirichletCondition[u[x, y] == 0, True];

Calcule seis valores propios y funciones propias del operador.

In[4]:=
Click for copyable input
{vals, funs} = NDEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x, y], {x, y} \[Element] \[CapitalOmega], 6];

Inspeccione los valores propios.

In[5]:=
Click for copyable input
vals
Out[5]=

Visualice la parte real de las funciones propias.

muestre la entrada completa de Wolfram Language
In[6]:=
Click for copyable input
Grid[Partition[ Plot3D[Re[#], {x, y} \[Element] \[CapitalOmega], ColorFunction -> "TemperatureMap", Boxed -> False, Axes -> None, PlotRange -> All, PlotStyle -> {Specularity[White, 20]}, Method -> {"ShrinkWrap" -> True}] & /@ funs, 3], Background -> Transparent] // Quiet
Out[6]=

Ejemplos relacionados

de en fr ja ko pt-br ru zh