Язык Wolfram Language

Дифференциальные системы собственных векторов

Моделирование малых колебаний в молекуле CO

В экспериментальных условиях молекула СО колеблется около равновесной длины с эффективной жесткостью пружины . Колебания регулируются уровнением квантового гармонического осциллятора. В дальнейшем, является уменьшенной массой молекулы, является естественной частотой колебаний, представляет смещение от положения равновесия, и является постоянной Планка.

In[1]:=
Click for copyable input
qho = -(\[HBar]^2/(2 m)) Laplacian[u[x], {x}] + (m \[Omega]^2)/ 2 x^2 u[x];

Вычислим первые четыре собственных значения и нормированные собственные функции.

In[2]:=
Click for copyable input
sol = DEigensystem[qho, u[x], {x, -\[Infinity], \[Infinity]}, 4, Assumptions -> \[HBar] > 0 && m > 0 && \[Omega] > 0, Method -> "Normalize"]
Out[2]=

Предположим, что частица находится в равной суперпозиции четырех состояний. Как следствие, волновая функция будет иметь следующий вид: .

In[3]:=
Click for copyable input
\[Psi][x_, t_] = Total[MapThread[1/2 Exp[I E t #1/\[HBar]] #2 &, sol]]
Out[3]=

Определим три параметра, , , и с использованием базовых блоков атомных единиц массы, таких как фемтосекунды и пм, так как полученное значение будет близко единицe.

In[4]:=
Click for copyable input
m = QuantityMagnitude[( Entity["Element", "Carbon"][ EntityProperty["Element", "AtomicMass"]] Entity["Element", "Oxygen"][EntityProperty["Element", "AtomicMass"]])/( Entity["Element", "Carbon"][ EntityProperty["Element", "AtomicMass"]] + Entity["Element", "Oxygen"][ EntityProperty["Element", "AtomicMass"]]), "AtomicMassUnits"]
Out[4]=
In[5]:=
Click for copyable input
\[Omega] = Sqrt[QuantityMagnitude[Quantity[1.86, "Kilonewtons"/"Meters"], "AtomicMassUnit"/"Femtoseconds"^2]/m]
Out[5]=
In[6]:=
Click for copyable input
\[HBar] = QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"], "AtomicMassUnit"*"Picometers"^2/"Femtoseconds"]
Out[6]=

Функция плотности вероятности смещения задается следующим выражением: .

In[7]:=
Click for copyable input
\[Rho][x_, t_] = FullSimplify[ComplexExpand[Conjugate[\[Psi][x, t]] \[Psi][x, t]]]
Out[7]=

В качестве распределения вероятностей, интеграл над полем вещественных чисел равен 1 для всех значений .

In[8]:=
Click for copyable input
Chop[Integrate[\[Rho][x, t], {x, -\[Infinity], \[Infinity]}]]
Out[8]=

Визуализируем плотность вероятности с течением времени.

код на языке Wolfram Language целиком
In[9]:=
Click for copyable input
Animate[Plot[\[Rho][x, t], {x, -25, 25}, PlotRange -> {0, .16}, PlotTheme -> "Detailed", FrameLabel -> {Row[{x, RawBoxes@RowBox[{"(", "\"pm\"", ")"}]}, " "], None}, LabelStyle -> Larger, PlotLegends -> Placed[{Row[{HoldForm[\[Rho]][x, Quantity[NumberForm[t, {2, 1}], "Femtoseconds"]], RawBoxes@RowBox[{"(", SuperscriptBox["\"pm\"", -1], ")"}]}, " "]}, Above]], {t, 0., 5.7, ImageSize -> Small}, AnimationRate -> 1, SaveDefinitions -> True, Alignment -> Center]
Запустить анимацию
Остановить анимацию

Родственные примеры

de en es fr ja ko pt-br zh