Wolfram Language™

Modele pequenas oscilações em uma molécula de CO

Experimentalmente, uma molécula de CO oscila em torno do seu comprimento de equilíbrio com uma constante efetiva de elasticidade de . As oscilações são governados pela equação de oscilador harmônico quântico. A seguir, é a massa reduzida de uma molécula, é a frequência natural, é o deslocamento da posição de equilíbrio, e é a constante de Planck reduzida.

In[1]:=

qho = -(\[HBar]^2/(2 m)) Laplacian[u[x], {x}] + (m \[Omega]^2)/ 2 x^2 u[x];

Calcule os primeiros quatro valores e funções próprios normalizados.

In[2]:=

sol = DEigensystem[qho, u[x], {x, -\[Infinity], \[Infinity]}, 4, Assumptions -> \[HBar] > 0 && m > 0 && \[Omega] > 0, Method -> "Normalize"]

Out[2]=

Supondo que a partícula está em uma superposição igual dos quatro estados, a função de onda terá a forma .

In[3]:=

\[Psi][x_, t_] = Total[MapThread[1/2 Exp[I E t #1/\[HBar]] #2 &, sol]]

Out[3]=

Calcule os três parâmetros , , e usando unidades de base de unidades de massa atômica, femtossegundos, e picometros, enquanto os valores resultantes estarão perto de unidade de ordem.

In[4]:=

m = QuantityMagnitude[( Entity["Element", "Carbon"][ EntityProperty["Element", "AtomicMass"]] Entity["Element", "Oxygen"][EntityProperty["Element", "AtomicMass"]])/( Entity["Element", "Carbon"][ EntityProperty["Element", "AtomicMass"]] + Entity["Element", "Oxygen"][ EntityProperty["Element", "AtomicMass"]]), "AtomicMassUnits"]

Out[4]=

In[5]:=

\[Omega] = Sqrt[QuantityMagnitude[Quantity[1.86, "Kilonewtons"/"Meters"], "AtomicMassUnit"/"Femtoseconds"^2]/m]

Out[5]=

In[6]:=

\[HBar] = QuantityMagnitude[Quantity[1., "ReducedPlanckConstant"], "AtomicMassUnit"*"Picometers"^2/"Femtoseconds"]

Out[6]=

A função densidade de probabilidade do deslocamento é dada por .

In[7]:=

\[Rho][x_, t_] = FullSimplify[ComplexExpand[Conjugate[\[Psi][x, t]] \[Psi][x, t]]]

Out[7]=

Como uma distribuição de probabilidade, a integral de sobre os reais é 1 para todo .

In[8]:=

Chop[Integrate[\[Rho][x, t], {x, -\[Infinity], \[Infinity]}]]

Out[8]=

Visualize a densidade de probabilidade ao longo do tempo.

In[9]:=

Animate[Plot[\[Rho][x, t], {x, -25, 25}, PlotRange -> {0, .16}, PlotTheme -> "Detailed", FrameLabel -> {Row[{x, RawBoxes@RowBox[{"(", "\"pm\"", ")"}]}, " "], None}, LabelStyle -> Larger, PlotLegends -> Placed[{Row[{HoldForm[\[Rho]][x, Quantity[NumberForm[t, {2, 1}], "Femtoseconds"]], RawBoxes@RowBox[{"(", SuperscriptBox["\"pm\"", -1], ")"}]}, " "]}, Above]], {t, 0., 5.7, ImageSize -> Small}, AnimationRate -> 1, SaveDefinitions -> True, Alignment -> Center]

Reproduzir

Parar