Создание модели подвесной цепи

Найти положение с минимальной потенциальной энергией цепи или кабеля длины , провесающей между двумя точками.

Задать значения параметров для длины цепи , высоты левого конца , и высоты правого конца .

In[1]:=

L = 4; a = 1; b = 3;

Допустим, что является высотой цепи в функции горизонтальной позиции с .

In[2]:=

xf = 1; nh = 201; h := xf/nh;

Задать переменные для высоты цепи .

In[3]:=

varsy = Array[y, nh + 1, {0, nh}];

Указать уклон в положении через и задать его величину.

In[4]:=

varsm = Array[m, nh + 1, {0, nh}];

Указать частичную потенциальную энергию от до через .

In[5]:=

varsv = Array[v, nh + 1, {0, nh}];

Указать длину цепи в положении через и задать её величинy.

In[6]:=

varss = Array[s, nh + 1, {0, nh}];

Объединить все величины.

In[7]:=

vars = Join[varsm, varsy, varsv, varss];

Цель данного шага - минимизировать общую потенциальную энергию .

In[8]:=

objfn = v[nh];

Ниже представлены ограничения предельных значений, основанные на геометрическом строении.

In[9]:=

bndcons = {y[0] == a, y[nh] == b, v[0] == 0, s[0] == 0, s[nh] == L};

Дискретизировать обыкновенные дифференциальные уравнения: , , .

In[10]:=

odecons = {Table[ y[j + 1] == y[j] + 0.5*h*(m[j] + m[j + 1]), {j, 0, nh - 1}], Table[v[j + 1] == v[j] + 0.5* h*(y[j]*Sqrt[1 + m[j]^2] + y[j + 1]*Sqrt[1 + m[j + 1]^2]), {j, 0, nh - 1}], Table[s[j + 1] == s[j] + 0.5*h*(Sqrt[1 + m[j]^2] + Sqrt[1 + m[j + 1]^2]), {j, 0, nh - 1}]};

Выберать начальные точки для величин.

In[11]:=

tmin = If[b > a, 0.25 , 0.75]; init = Join[Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}], Table[4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a, {k, 0, nh}], Table[(4*Abs[b - a]*(k/nh)*(0.5*(k/nh) - tmin) + a)*4* Abs[b - a]*((k/nh) - tmin), {k, 0, nh}], Table[4*Abs[b - a]*((k/nh) - tmin), {k, 0, nh}]];

Минимизировать общую потенциальную энергию, основываясь на ограничениях.

In[12]:=

sol = FindMinimum[{objfn, Join[bndcons, odecons]}, Thread[{vars, init}]];

Извлечь точки решения.

In[13]:=

solpts = Table[{i h, y[i] /. sol[[2]]}, {i, 0, nh}];

Графически изобразить положение цепи с минимальной потенциальной энергией.

In[14]:=

ListPlot[solpts, ImageSize -> Medium, PlotTheme -> "Marketing"]

Out[14]=

Используйте FindFit для подгонки результата до цепной линии.

In[15]:=

catenary[t_] = c1 + (1/c2) Cosh[c2 (t - c3)];

In[16]:=

fitsol = FindFit[solpts, catenary[t], {c1, c2, c3}, {t}]

Out[16]=

Графически изобразите точки решения вместе с цепной линией.

In[17]:=

Show[Plot[catenary[t] /. fitsol, {t, 0, 1}, PlotStyle -> Directive[Green, Thickness[0.01]], ImageSize -> Medium], ListPlot[Take[solpts, 1 ;; nh ;; 5], PlotStyle -> PointSize[.02]]]

Out[17]=