Eigenwerte in einem Intervall berechnen: Neu in Wolfram Language 11

Eigenwerte in einem Intervall berechnen

Bestimmen Sie eine Region.

In[1]:=

\[CapitalOmega] = 
  ImplicitRegion[(x^2 + y^2 + 2 y)^2 < 4 (x^2 + y^2), {x, y}];

Bestimmen Sie einen Laplace-Operator.

In[2]:=

\[ScriptCapitalL] = -Laplacian[u[x, y], {x, y}];

Bestimmen Sie eine Dirichlet-Randbedingung.

In[3]:=

\[ScriptCapitalB] = DirichletCondition[u[x, y] == 0, True];

Ermitteln Sie einen Eigenwert in einem bestimmten Intervall und die entsprechende Eigenfunktion unter Vewendung eines verfeinerten Gitternetzes.

In[4]:=

{vals, funs} = 
 NDEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, 
  u, {x, y} \[Element] \[CapitalOmega], 1, 
  Method -> {"Eigensystem" -> {"FEAST", "Interval" -> {400, 405}}, 
    "SpatialDiscretization" -> {"FiniteElement", 
      "MeshOptions" -> {"MaxCellMeasure" -> 0.001}}}]

Out[4]=

Visualisieren Sie die ermittelte Eigenfunktion.

Den kompletten Wolfram Language-Input zeigen

In[5]:=

ContourPlot[
 Evaluate[Abs[funs[[1]][x, y]]^(1/2)], {x, y} \[Element] 
  funs[[1]]["ElementMesh"], PlotPoints -> 200, 
 ColorFunction -> (GrayLevel[1 - #] &), AspectRatio -> Automatic, 
 ContourStyle -> None, PlotRange -> All, MaxRecursion -> 0]

Out[5]=