Wolfram Language

Differentialgleichungen mit Eigensystemen

AharonovBohm-Eigenwerte ermitteln

Der AharonovBohm-Effekt ist ein quantenmechanisches Phänomen, bei dem ein geladenes Teilchen von elektromagnetischem Potentialc beeinflusst wird, obwohl das Magnetfeld innerhalb des Gebiets wo sich das Teilchen bewegt, Null ist. In diesem Beispiel ziehen wir die Schrödingergleichung für ein fixiertes Magnetfeld, das sich an der lotrechten Geraden zur Gebiet des Teilchens konzentiert, hinzu.

Spezifizieren Sie das Gebiet als Sektor in der -Ebene

In[1]:=
Click for copyable input
\[CapitalOmega] = Disk[{0, 0}, 1, {-\[Pi]/8, \[Pi]/8}];

Spezifizieren Sie den AharonovBohm-Operator. Das Magnetfeld ist auf die -Achse beschränkt.

In[2]:=
Click for copyable input
A = 1/2 {-(y - b), x - a}/((x - a)^2 + (y - b)^2) /. {a -> 0.2, b -> 0.4}; \[ScriptCapitalL] = -Laplacian[u[x, y], {x, y}] + I Div[A, {x, y}] u[x, y] + 2 I A.D[u[x, y], {{x, y}}] + A.A u[x, y];

Spezifizieren Sie Dirichlet-Randbedingungen auf dem gesamten Rand.

In[3]:=
Click for copyable input
\[ScriptCapitalB] = DirichletCondition[u[x, y] == 0, True];

Berechnen Sie sechs Eigenwerte und Eigenfunktionen des Operators.

In[4]:=
Click for copyable input
{vals, funs} = NDEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]}, u[x, y], {x, y} \[Element] \[CapitalOmega], 6];

Untersuchen Sie die Eigenwerte.

In[5]:=
Click for copyable input
vals
Out[5]=

Visualisieren Sie den reellen Teil der Eigenfunktionen.

Den kompletten Wolfram Language-Input zeigen
In[6]:=
Click for copyable input
Grid[Partition[ Plot3D[Re[#], {x, y} \[Element] \[CapitalOmega], ColorFunction -> "TemperatureMap", Boxed -> False, Axes -> None, PlotRange -> All, PlotStyle -> {Specularity[White, 20]}, Method -> {"ShrinkWrap" -> True}] & /@ funs, 3], Background -> Transparent] // Quiet
Out[6]=

Verwandte Beispiele

en es fr ja ko pt-br ru zh