Die symbolischen Eigenfunktionen eines 1D-Laplace-Operators ermitteln
Spezifizieren Sie einen eindimensionalen Laplace-Operator.
In[1]:=
\[ScriptCapitalL] = -Laplacian[u[x], {x}];
Spezifizieren Sie homogene Dirichlet-Randbedingungen für die Eigenfunktionen.
In[2]:=
\[ScriptCapitalB]1 = DirichletCondition[u[x] == 0, True];
Ermitteln Sie die fünf kleinsten Eigenwerte und Eigenfunktionen.
In[3]:=
{vals, funs} =
DEigensystem[{\[ScriptCapitalL], \[ScriptCapitalB]1},
u[x], {x, 0, \[Pi]}, 5];
Untersuchen Sie die Eigenwerte.
In[4]:=
vals
Out[4]=
Untersuchen Sie die Eigenfunktionen.
In[5]:=
funs
Out[5]=
Visualisieren Sie die Eigenfunktionen.
In[6]:=
Plot[Evaluate[funs + 2 Range[5]], {x, 0, \[Pi]}]
Out[6]=
Spezifizieren Sie eine homogene Neumann-Randbedingung.
In[7]:=
\[ScriptCapitalB]2 = NeumannValue[0, True];
Ermitteln Sie die fünf kleinsten Eigenwerte und Eigenfunktionen.
In[8]:=
{vals, funs} =
DEigensystem[\[ScriptCapitalL] + \[ScriptCapitalB]2,
u[x], {x, 0, \[Pi]}, 5];
Untersuchen Sie die Eigenwerte. Bezüglich der Dirichlet-Bedingungen wurde ein Nullmodus hinzugefügt.
In[9]:=
vals
Out[9]=
Sinusse ersetzen Kosinusse in den Egenfunktionen.
In[10]:=
funs
Out[10]=
Visualisieren Sie die Eigenfunktionen.
In[11]:=
Plot[Evaluate[funs + 2 Range[5]], {x, 0, \[Pi]}]
Out[11]=